Detection: High Frequency Copy Of Files In Network Share

Description

The following analytic detects a high frequency of file copying or moving within network shares, which may indicate potential data sabotage or exfiltration attempts. It leverages Windows Security Event Logs (EventCode 5145) to monitor access to specific file types and network shares. This activity is significant as it can reveal insider threats attempting to transfer classified or internal files, potentially leading to data breaches or evidence tampering. If confirmed malicious, this behavior could result in unauthorized data access, data loss, or compromised sensitive information.

Search

 1`wineventlog_security`
 2EventCode=5145
 3RelativeTargetName IN (
 4    "*.7z", "*.bmp", "*.db", "*.doc", "*.docx",
 5    "*.gif", "*.gz", "*.jpg", "*.key", "*.log",
 6    "*.pdf", "*.png", "*.ppt", "*.pptx", "*.rar",
 7    "*.rtf", "*.tar", "*.txt", "*.xls", "*.xlsx", "*.zip"
 8)
 9ObjectType=File
10ShareName IN (
11    "\\\\*\\Admin$",
12    "\\\\*\\C$",
13    "\\\\*\\IPC$"
14)
15
16| eval AccessMask_ = tonumber(AccessMask, 16)

We Select only write-related operations: 0x2 = WriteData (create/write file) 0x4 = AppendData (append to file)

1
2
3| where (bit_and(AccessMask_, 2) != 0) OR (bit_and(AccessMask_, 4) != 0)
4
5
6| bucket _time span=5m

Count write events per host, user and source IP within each time window

 1
 2| stats
 3    values(RelativeTargetName) AS valRelativeTargetName
 4    values(ShareName) AS valShareName
 5    values(ObjectType) AS valObjectType
 6    values(AccessMask) AS valAccessMask
 7    values(src_port) AS valSrcPort
 8    values(SourceAddress) AS valSrcAddress
 9    count AS numFileWriteEvents
10BY dest _time EventCode src_user src_ip

Build a historical baseline for each destination host and user using the average and standard deviation of previous buckets

 1
 2
 3| eventstats
 4    avg(numFileWriteEvents) AS avgFileWriteEvents
 5    stdev(numFileWriteEvents) AS stdFileWriteEvents
 6    count AS numSlots
 7BY dest EventCode src_user
 8
 9
10| eval upperThreshold=avgFileWriteEvents + (stdFileWriteEvents * 3)
11
12| eval isOutlier=if(
13    numFileWriteEvents > 20
14    AND (
15        numSlots < 5
16        OR numFileWriteEvents >= upperThreshold
17    ),
18    1,
19    0
20)
21
22| where isOutlier=1
23
24| `high_frequency_copy_of_files_in_network_share_filter`

Data Source

Name	Platform	Sourcetype	Source
Windows Event Log Security 5145	Windows	'XmlWinEventLog'	'XmlWinEventLog:Security'

Macros Used

Annotations

Default Configuration

This detection is configured by default in Splunk Enterprise Security to run with the following settings:

Implementation

To successfully implement this search, you need to be ingesting Windows Security Event Logs with 5145 EventCode enabled. The Windows TA is also required. Also enable the object Audit access success/failure in your group policy.

Known False Positives

This behavior may be seen in normal transfer of files within a network if network shares are commonly used for sharing documents.

Associated Analytic Story

• Information Sabotage

• Hellcat Ransomware

• Insider Threat

Intermediate Findings

Threat Objects

References

• https://attack.mitre.org/techniques/T1537/

• https://learn.microsoft.com/en-us/previous-versions/windows/it-pro/windows-10/security/threat-protection/auditing/event-5145#table-of-file-access-codes

Detection Testing

Replay any dataset to Splunk Enterprise by using our replay.py tool or the UI. Alternatively you can replay a dataset into a Splunk Attack Range

Source: GitHub |

Version: 11